.data
	.align	2
_sccsid:.data	2
L12:	.ascii	"@(#)procint.c\11"
	.ascii	"1.1 (UKC) 19/9/85\0"
	.data
	.long	L12
	.lcomm	_pixel, 1024
	.lcomm	_gap, 4096
	.data	1
L54:	.ascii	"pixel file write error\0"

	.text
LL0:	.align	1
	.globl	_process
_process:.word	0xfc0
	subl2	$44, sp
	movd	_orig_real, -24(fp)	# o_real
	movd	_orig_imag, -32(fp)	# o_imag
	cvtld	_npixel, r0
	divd3	r0, _side, -40(fp)	# o_side
	clrl	r11			# count
L2001:	cvtld	r11, r0
	muld2	-40(fp), r0
	addd3	-24(fp), r0, _gap[r11]
	aoblss	_npixel, r11, L2001

	clrl	-44(fp)			# i
L2007:	cvtld	-44(fp), r0
	muld2	-40(fp), r0
	addd3	-32(fp), r0, -16(fp)	# c_imag
	subl3	$1, _npixel, r10	# j (loop goes from npixel-1 to 0)
L2005:	movd	_gap[r10], -8(fp)	# c_real
	movd	-8(fp), r8		# z_real
	movd	-16(fp), r6		# z_imag
	movl	_niter, r11		# count
L2003:	muld3	r8, r8, r4		## w_real
	muld3	r6, r6, r2		## w_imag
	addd3	r2, r4, r0		##
	cmpd	r0, $0d4.0		##
	bgtr	L46			##
	muld2	r8, r6			##
	addw2	$0x80, r6		## muld2	$0d2.0, r6
	addd2	-16(fp), r6		##
	subd3	r2, r4, r8		##
	addd2	-8(fp), r8		##
	sobgtr	r11, L2003		##

L46:	subw3	r11, _niter, r11
	movw	r11, _pixel[r10]
	incl	_hist[r11]
	sobgeq	r10, L2005

	pushl	_pixfd
	pushl	$1
	ashl	$1, _npixel, -(sp)
	pushal	_pixel
	calls	$4, _fwrite
	movl	_pixfd, r0
	bbs	$5, 16(r0), L39
#	aoblss	_npixel, -44(fp), L2007	# too far
	incl	-44(fp)
	cmpl	-44(fp), _npixel
	bgeq	L2000
	brw	L2007

L39:	pushal	L54
	calls	$1, _perror
L2000:	ret